         MACRO                                                          02000000
&NAME    STCLEAR &STRING=               PROTOTYPE                       04000000
.********************************************************************** 06000000
.*                                                                    * 08000000
.*RELEASE 23 DELETIONS                                                * 10000000
.*                                                                    * 12000000
.*RELEASE 22 DELETIONS                                                * 14000000
.*                                                                    * 16000000
.*RELEASE 21 DELETIONS                                                * 18000000
.*                                                                    * 20000000
.*STATUS - CHANGE LEVEL 000                                           * 22000000
.*                                                                    * 24000000
.*NAME - STCLEAR                                                      * 26000000
.*                                                                    * 28000000
.*FUNCTION - THIS MACRO IS USED TO SPECIFY THE CHARACTER STRING THAT  * 30000000
.*   WILL BE USED TO REQUEST THAT A DISPLAY STATION SCREEN CAN BE     * 32000000
.*   ERASED.                                                          * 34000000
.*                                                                    * 36000000
.*       THE MACRO PROTOTYPE IS ABOVE                                 * 38000000
.*                                                                    * 40000000
.*       THE STANDARD FORM OF THE EXPANSION IS BELOW                  * 42000000
.*NAME   LA    1,CHAR                   PUT ADDR OF CHAR STRING IN REG* 44000000
.*       LA    0,16                     LOAD ENTRY CODE               * 46000000
.*       SLL   0,24                     PUT ENTRY CODE IN HIGH ORDER  * 48000000
.*       SVC   94                       ISSUE STATUS SVC              * 50000000
.*                                                                    * 52000000
.********************************************************************** 54000000
         AIF   ('&STRING' EQ '').ERROR                                  56000000
         AIF   ('&STRING' EQ '0').ZERO                                  58000000
         AIF   ('&STRING'(1,1) EQ '(').REG                              60000000
&NAME    LA    1,&STRING .              PUT ADDR OF CHAR STRING IN REG  62000000
         AGO   .ENTRYCD .                                               64000000
.REG     ANOP                                                           66000000
&NAME    LR    1,&STRING .              PUT ADDR OF CHAR STRING IN REG  68000000
         AGO   .ENTRYCD                                                 70000000
.ZERO    ANOP                                                           72000000
&NAME    SR    1,1 .                    ZERO OUT REG                    74000000
.ENTRYCD LA    0,16 .                   LOAD ENTRY CODE                 76000000
         SLL   0,24 .                   PUT ABOVE IN HIGH ORDER         78000000
         SVC   94 .                     ISSUE STATUS SVC                80000000
         AGO   .EXIT                                                    82000000
.ERROR   IHBERMAC 24                                                    84000000
.EXIT    ANOP                                                           86000000
         MEND                                                           88000000
