         MACRO                                                          00400020
&NAME    TPUT  &BFF,&SIZE,&EDIT,&WAIT,&HOLD,&BRKI,&PRTY,&TJID=,        *00600021
               &TJIDLOC=                                                00800021
.*********************************************************************. 01200020
.*                                                                   *. 01600020
.*RELEASE 23 DELETIONS                                               *. 02000020
.*                                                                   *. 02400020
.*RELEASE 22 DELETIONS                                               *. 02800020
.*                                                                   *. 03200020
.*RELEASE 21 DELETIONS                                               *. 03600020
.*                                                                   *. 04000020
.*STATUS - CHANGE LEVEL 001                                     SA60002 04400000
.*                                                                   *. 04800020
.*NAME - TPUT                                                        *. 05200020
.*                                                                   *. 05600020
.*FUNCTION - THE TPUT MACRO IS USED TO MOVE A RECORD FROM THE USER'S *. 06000020
.*   BUFFER TO A TS OUTPUT BUFFER TO BE TRANSMITTED TO A TERMINAL.   *. 06400020
.*                                                                    * 06800020
.*********************************************************************. 07200020
.*                                                                      07600020
.*  TPUT BUFFER ADDR,BUFFER SIZE,EDIT   ,WAIT  ,NOHOLD,NOBREAK,HIGHP    08000021
.*        (2-12)      (2-12)     ASIS    NOWAIT HOLD   BREAKIN LOWP     08400021
.*                               CONTROL                                08800021
.*                               FULLSCR                        SA60002 08850000
.*       TJID=XX   (EDIT,WAIT,NOHOLD,NOBREAK,HIGHP ARE DEFAULTS)        09200021
.*                                                                      09600020
.*        TJIDLOC=ADDR                                                  10000020
.*                                                                      10400020
         LCLA  &OPT                                                     10800020
         LCLA  &RET                                                     11200020
         LCLB  &E,&W,&H,&B,&P                                           11500021
         LCLC  &PARM,&ID                                                11800020
&ID      SETC  '0'                      SET TJID TO '0'                 12100020
         AIF   ('&BFF' EQ '' OR '&SIZE' EQ '').ERROR1  MNOTE            12800020
         AIF   ('&TJID' NE '' AND '&TJIDLOC' NE '').ERROR2  MNOTE       13200020
         AIF   ('&EDIT' EQ 'R').RF      CHECK FOR R FORM                13600020
&PARM    SETC  '&EDIT'                                                  14600020
.CKPARM  ANOP                                                           15600020
&RET     SETA  &RET+1                                                   16600020
         AIF   ('&PARM' EQ '').RET           NULL, TRY NEXT             17600020
         AIF   ('&PARM' EQ 'EDIT').EDI       SET EDIT                   18600020
         AIF   ('&PARM' EQ 'ASIS').ASI       SET ASIS                   19600020
         AIF   ('&PARM' EQ 'CONTROL').CON    SET CONTROL                20600020
         AIF   ('&PARM' EQ 'FULLSCR').FULLS SET FULL SCREEN     SA60002 20650000
         AIF   ('&PARM' EQ 'WAIT').WAI       SET WAIT                   21600020
         AIF   ('&PARM' EQ 'NOWAIT').NOW     SET NOWAIT                 22600020
         AIF   ('&PARM' EQ 'HOLD').HOL       SET HOLD                   23600020
         AIF   ('&PARM' EQ 'NOHOLD').NOH     SET NOHOLD                 24600020
         AIF   ('&PARM' EQ 'NOBREAK').NOB    SET NOBREAK                25600020
         AIF   ('&PARM' EQ 'BREAKIN').BRE    SET BREAKIN                26600020
         AIF   ('&PARM' EQ 'HIGHP').HPR      SET HIGHP                  26900021
         AIF   ('&PARM' EQ 'LOWP').LPR       SET LOWP                   27200021
         AGO   .ERROR3                                                  27600020
.*                                                                      34400020
.*  CHECK REGISTER NOTATION IS USED                                     34800020
.*                                                                      35200020
.CHKREG  SPACE 1                                                        35600020
         AIF   ('&BFF'(1,1) EQ '(' OR '&SIZE'(1,1) EQ '(').REGFM  REG.  36000020
.*                                      FORM MACRO                      36400020
         AIF   ('&TJID' EQ '').CHKLOC   GOTO CHECK TJIDLOC              36800020
         AIF   ('&TJID'(1,1) EQ '(').REGFM   REG. FORM MACRO            37200020
&ID      SETC  '&TJID'                  SET TJID                        37600020
         AGO   .EXPAND                  GOTO EXPANSION                  38000020
.CHKLOC  AIF   ('&TJIDLOC' EQ '').EXPAND  GO EXPAND IF NO 'TJIDLOC'     38400021
         AIF   ('&TJIDLOC'(1,1) EQ '(').REGFM  REG. FORM MACRO          38800020
.*                                                                      39200020
.*   REGULAR FORMAT OF MACRO                                            39600020
.*                                                                      40000020
.EXPAND  CNOP  0,4                                                      40400020
         AIF   ('&TJIDLOC' NE '').LOC   TJLOC SPECIFIED                 40800020
&NAME    B     *+12                     BRANCH AROUND CONSTANTS         41200020
         DC    AL2(&ID)                 TJID                            41600020
         DC    AL2(&SIZE)               BUFFER SIZE                     42000020
         DC    AL1(&OPT)                OPTIONS                         42400020
         DC    AL3(&BFF)                BUFFER ADDR                     42800020
         LM    0,1,*-8                  LOAD PARAMETER REGISTERS        43200020
.SVC     SVC   93                       ISSUE TGET/TPUT SVC             43600020
         SPACE 1                                                        44000020
         MEXIT                                                          44400020
.*                                                                      44800020
.*   TJIDLOC IS SPECIFIED                                               45200020
.*                                                                      45600020
.LOC     ANOP                                                           46000020
&NAME    IC    0,&TJIDLOC               LOAD 1ST BYTE OF TJID           46400020
         SLL   0,8                      SHIFT IT                        46800020
         IC    0,&TJIDLOC+1             LOAD 2ND BYTE OF TJID           47200020
         SLL   0,16                     SHIFT TJID TO HI-ORDER BYTE     47600020
         AIF   (&OPT EQ 0).ZERO         BRANCH IF OPTIONS ARE ZERO      47800021
         O     0,*+8                    LOAD BUFFER SIZE                48000020
         B     *+12                     BRANCH AROUND CONSTANT          48400020
         DC    AL2(0)                   TJID                            48800020
         DC    AL2(&SIZE)               BUFFER SIZE                     49200020
         DC    AL1(&OPT)                OPTIONS                         49600020
         DC    AL3(&BFF)                BUFFER ADDR                     50000020
         L     1,*-4                    LOAD OPTIONS & BUFFER ADDR      50400021
         AGO   .SVC                     GOTO ISSUE SVC                  50800020
.ZERO    LA    1,&SIZE                  LOAD BUFFER SIZE                50880021
         OR    0,1                      OR IT INTO REGISTER 1           50960021
         LA    1,&BFF                   Z HIGH ORDR BYTE & LD BFR ADDR  51040021
         AGO   .SVC                     GOTO ISSUE SVC                  51120021
.*                                                                      51200020
.*   REGISTER FORMAT                                                    51600020
.*                                                                      52000020
.REGFM   AIF   ('&TJIDLOC' EQ '').NOLOC   SKIP IF TJIDLOC NOT SPECIFIED 52400020
         AIF   ('&TJIDLOC'(1,1) EQ '(').REGLOC    LOC IN REG  FORM      52800020
&NAME    IC    15,&TJIDLOC              INSERT 1ST BYTE OF TJID         53200020
         SLL   15,8                     MOVE IT TO NEXT BYTE            53600020
         IC    15,&TJIDLOC+1            INSERT 2ND BYTE OF TJID         54000020
         SLL   15,16                    MOVE TJID TO HI-ORDER 2 BYTES   54400020
         AGO   .CHKSIZE                 GOTO CHECK SIZE                 54800020
.REGLOC  ANOP                                                           55200020
&NAME    IC    15,0(,&TJIDLOC(1))       INSERT 1ST BYTE OF TJID         55600021
         SLL   15,8                     MOVE IT TO NEXT BYTE            56000020
         IC    15,1(,&TJIDLOC(1))       INSERT 2ND BYTE OF TJID         56400021
         SLL   15,16                    MOVE TJID TO HI-ORDER 2 BYTES   56800020
         AGO   .CHKSIZE                 GOTO CHECK SIZE                 57200020
.*                                                                      57600020
.*   WHEN TJIDLOC IS NOT SPECIFIED                                      58000020
.*                                                                      58400020
.NOLOC   AIF   ('&TJID' NE '').TJIDYES                                  58800020
&NAME    DS    0H                       TJID IS '0'                     59200021
         AGO   .CHKSIZE                 GOTO CHECK SIZE                 59600020
.TJIDYES AIF   ('&TJID'(1,1) EQ '(').IDREG   TJID IN REG FORM           60000020
&NAME    LA    15,&TJID                 LOAD TJID                       60400020
         AGO   .SHIFT                   GOTO SHIFT REG.0                60800020
.IDREG   ANOP                                                           61200020
&NAME    LR    15,&TJID(1)              LOAD TJID IN REG 0              61600021
.SHIFT   SLL   15,16                    SHIFT TJID TO HI-ORDER BYTE     62000020
.*                                                                      62400020
.*   CHECK SIZE OF BUFFER (BY NOW TJID IS IN HI-ORDER 2 BYTES OF REG 0) 62800020
.*                                                                      63200020
.CHKSIZE AIF   ('&SIZE'(1,1) EQ '(').SZREG   SKIP IF SIZE IN REG        63600020
         LA    0,&SIZE                  LOAD SIZE IN REG.0              64000020
         AGO   .ORSIZE                  GOTO OR SIZE                    64400020
.SZREG   AIF   ('&SIZE' EQ '(0)').ORSIZE  GOTO SET SIZE IN REG. 0       64800020
         LR    0,&SIZE(1)               LOAD BUFFER SIZE                65200021
.ORSIZE  AIF   ('&TJID' EQ '' AND '&TJIDLOC' EQ '').PAST                65400021
         OR    0,15                     LOAD TJID + BUFFER SIZE         65600021
.PAST    AIF   (&OPT EQ 0 AND '&BFF'(1,1) EQ '(').ORONE                 65800021
         AIF   (&OPT EQ 0 AND '&BFF'(1,1) NE '(').ZOPT ZERO OPTN        65900021
         CNOP  0,4                                                      66000020
         B     *+8                                                      66400020
         DC    AL1(&OPT)                OPTION BITS                     66800020
         AIF   ('&BFF'(1,1) EQ '(').REGGO   BFFR IN REG.                67200020
         DC    AL3(&BFF)                BUFFER ADDR                     67600020
         L     1,*-4                    LOAD PARAMETER IN REG.1         68000020
         AGO   .SVC                     GOTO ISSUE SVC                  68400020
.ZOPT    LA    1,&BFF                   LOAD BUFFER ADDR IN REG 1       68500021
         AGO   .SVC                     ISSUE SVC                       68600021
.REGGO   DC    AL3(0)                   BUFFER ADDR                     68800020
         AIF   ('&BFF' EQ '(1)').ORONE  GOTO OR OPTIONS                 69200020
         L     1,*-4                    LOAD OPTIONS                    69600020
         OR    1,&BFF(1)                SET OPTIONS AND BUFFER ADDR     70000021
         AGO   .SVC                     GOTO ISSUE SVC                  70400020
.ORONE   LA    1,0(,&BFF(1))            CLR HIGH ORDR BYTE + LD BFR ADR 70600021
         AIF   (&OPT EQ 0).SVC          GOTO ISSUE SVC IF OPT EQ 0      70800021
         O     1,*-8                    SET OPTIONS                     71000021
         AGO   .SVC                                                     71200020
.EDI     ANOP                                                           71600020
         AIF   (&E).ERROR2              DUP OPTION                      72000020
&E       SETB  1                        EDIT OPTION SPECFIED            72400020
         AGO   .RET                                                     72800020
.ASI     ANOP                                                           73200020
         AIF   (&E).ERROR2              DUP OPTION                      73600020
&E       SETB  1                        EDIT OPTION SPECFIED            74000020
&OPT     SETA  &OPT+1                   SET EDIT=ASIS                   74400020
         AGO   .RET                                                     74800020
.CON     ANOP                                                           75200020
         AIF   (&E).ERROR2              DUP OPTION                      75600020
&E       SETB  1                        EDIT OPTION SPECFIED            76000020
&OPT     SETA  &OPT+2                   SET EDIT=CONTROL                76400020
         AGO   .RET                                                     76800020
.FULLS   ANOP                                                   SA60002 76850000
         AIF   (&E).ERROR2              DUP OPTION              SA60002 76900000
&E       SETB  1                        EDIT OPTION SPECIFIED   SA60002 76950000
&OPT     SETA  &OPT+3                   CNTL+ASIS FOR FULLSCR   SA60002 77000000
         AGO   .RET                                             SA60002 77100000
.WAI     ANOP                                                           77200020
         AIF   (&W).ERROR2              DUP OPTION                      77600020
&W       SETB  1                        WAIT OPTION SPECIFIED           78000020
         AGO   .RET                                                     78400020
.NOW     ANOP                                                           78800020
         AIF   (&W).ERROR2              DUP OPTION                      79200020
&W       SETB  1                        WAIT OPTION SPECIFIED           79600020
&OPT     SETA  &OPT+X'10'               SET WAIT=NOWAIT                 80000020
         AGO   .RET                                                     80400020
.HOL     ANOP                                                           80800020
         AIF   (&H).ERROR2              DUP OPTION                      81200020
&H       SETB  1                        HOLD OPTION SPECIFIED           81600020
&OPT     SETA  &OPT+X'08'               SET HOLD=HOLD                   82000020
         AGO   .RET                                                     82400020
.NOH     ANOP                                                           82800020
         AIF   (&H).ERROR2              DUP OPTION                      83200020
&H       SETB  1                        HOLD OPTION SPECIFIED           83600020
         AGO   .RET                                                     84000020
.BRE     ANOP                                                           84400020
         AIF   (&B).ERROR2              DUP OPTION                      84800020
&B       SETB  1                        BREAK OPTION SPECIFIED          85200020
&OPT     SETA  &OPT+X'04'               SET BREAKIN                     85600020
         AGO   .RET                                                     86000020
.NOB     ANOP                                                           86400020
         AIF   (&B).ERROR2              DUP OPTION                      86800020
&B       SETB  1                        BREAK OPTION SPECIFIED          87200020
         AGO   .RET                                                     87240021
.HPR     ANOP                                                           87280021
         AIF   (&P).ERROR2              DUP OPTION                      87320021
&P       SETB  1                        PRIORITY OPTION SPECIFIED       87360021
         AGO   .RET                                                     87400021
.LPR     ANOP                                                           87440021
         AIF   (&P).ERROR2              DUP OPTION                      87480021
&P       SETB  1                        PRIORITY OPTION SPECIFIED       87520021
&OPT     SETA  &OPT+X'20'               SET  LOW PRIORITY OPTION        87560021
.RET     ANOP                                                           87600020
&PARM    SETC  '&WAIT'                                                  87900020
         AIF   ('&RET' EQ '1').CKPARM   CHECK WAIT                      88200020
&PARM    SETC  '&HOLD'                                                  88500020
         AIF   ('&RET' EQ '2').CKPARM   CHECK HOLD                      88800020
&PARM    SETC  '&BRKI'                                                  89100020
         AIF   ('&RET' EQ '3').CKPARM   CHECK BRKI                      89400020
&PARM    SETC  '&PRTY'                                                  89500021
         AIF   ('&RET' EQ '4').CKPARM   CHECK PRTY                      89600021
         AGO   .CHKREG                  DONE WITH OPTIONS               89700020
.RF      ANOP                                                           90000020
         AIF   ('&WAIT' NE '' OR '&HOLD' NE '' OR '&BRKI' NE '' OR '&PRX90400021
               TY' NE '' OR '&TJID' NE '' OR '&TJIDLOC' NE '').RERR     90800021
         AIF   ('&BFF'(1,1) NE '(' OR '&SIZE'(1,1) NE '(').RERR         91200020
&NAME    DS    0H                                                       91400020
         AIF   ('&BFF' EQ '(1)').SIZE                                   91600020
         LR    1,&BFF(1)                LOAD OPTIONS & BUFFER ADDR      92000021
.SIZE    AIF   ('&SIZE' EQ '(0)').SVC                                   92400020
         LR    0,&SIZE(1)               LOAD TJID & BUFFER SIZE         92800021
         AGO   .SVC                                                     93200020
.RERR    IHBERMAC 192                                                   93600020
         MEXIT                                                          94000020
.ERROR1  IHBERMAC 24                                                    94400020
         MEXIT                                                          94800020
.ERROR2  IHBERMAC 54,,,                                                 95200020
         MEXIT                                                          95600020
.ERROR3  IHBERMAC 49,,&PARM                                             96000020
         MEND                                                           96400020
