         MACRO                                                          00100057
&NAM     TSOMCP &OPTIONS=,&TRACE=0,&LNUNITS=,&UNITSIZ=60,              X00200057
               &DTRACE=0,&OLTEST=0                                      00300057
.*                                                                      00400057
.*      OS 218   PTF                                                    00500057
.*0000685000                                                   @SA76623 00600057
.*0000374560-374600                                            @SA75977 00700057
.*0000290000                                                   @SA73586 00800057
.*                                                                      00900057
.*       RELEASE 21.8, 09/20/73, CHANGE LEVEL=02                SA59163 01000057
.*D671030,671100                                                SA59196 01100057
.*A407700-407720                                                SA65439 01200057
.*C410000-411000                                                SA65439 01300057
.*C684000,685000                                                SA70240 01400057
.*A685500-685800                                                SA70240 01500057
.* C866000,869000                                              @YA14062 01550057
.* C338800                                                     @OZ16602 01550157
*C520000-521000                                                @OS78355 01550257
.*                                                                      01600057
.*                                                                      01700057
.*FUNCTION -- THIS MACRO USES THE VALUES PLACED IN GLOBAL VARIABLES     01800057
.*   BY PREVIOUS LINEGRP AND LIST MACROS AND THE VALUES SPECIFIED       01900057
.*   IN ITS OWN MACRO PARAMETERS TO GENERATE THE TCAM SOURCE            02000057
.*   STATEMENTS WHICH CONSTITUTE A MESSAGE CONTROL PROGRAM.             02100057
.*                                                                      02200057
.*ENTRY POINTS -- NOT APPLICABLE                                        02300057
.*                                                                      02400057
.*INPUT -- VALUES PLACED IN GLOBAL VARIABLES BY PREVIOUS MACRO CALLS    02500057
.*   AND MACRO CALL PARAMETER VALUES SPECIFIED BY THE USER.             02600057
.*                                                                      02700057
.*OUTPUT -- TCAM MACRO STATEMENTS.  MNOTES IF ERRORS ARE DETECTED.      02800057
.*                                                                      02900057
.*EXTERNAL REFERENCES -- NOT APPLICABLE                                 03000057
.*                                                                      03100057
.*EXITS, NORMAL -- NORMAL EXIT OCCURS AFTER A COMPLETE SOURCE MESSAGE   03200057
.*   CONTROL PROGRAM HAS BEEN GENERATED.                                03300057
.*                                                                      03400057
.*EXITS, ERROR -- IF PREVIOUS MACROS ENCOUNTERED SERIOUS                03500057
.*   ERRORS (QUITSW = 1) A MNOTE WITH SEVERITY 16 IS ISSUED             03600057
.*   AND GENERATION IS BYPASSED.                                        03700057
.*                                                                      03800057
.*TABLES/WORK AREAS -- SEE DESCRIPTIONS ACCOMPANYING VARIABLE           03900057
.*   DECLARATIONS.                                                      04000057
.*                                                                      04100057
.*ATTRIBUTES -- NOT APPLICABLE                                          04200057
.*                                                                      04300057
.*CHARACTER CODE DEPENDENCY -- NONE                                     04400057
.*                                                                      04500057
.*NOTES -- ERRORS IN PARAMETER VALUES RESULT IN SEVERITY 4 MNOTES, BUT  04600057
.*   DEFAULT VALUES ARE USED AND GENERATION CONTINUES.                  04700057
.*                                                                      04800057
.*   CHANGE DATE  12/17/75                                     @SA76623 04900057
.*                                                                      05000057
.*       GLOBAL VARIABLES                                               05100057
.*                                                                      05200057
         GBLA  &NLG                NUMBER OF LINEGRP MACROS ISSUED      05300057
         GBLB  &MCPSW              INDICATES TSOMCP MACRO ISSUED        05400057
         GBLB  &QUITSW             ON MEANS SERIOUS ERROR OCCURRED      05500057
         GBLB  &BISYNC             BISYNCHRONOUS LINE                   05600057
         GBLA  &ADRPT              ADCHAR ARRAY POINTER                 05700057
         GBLA  &SCRPT              USED AS POINTER TO ARRAYS WITH       05800057
.*                                 ONE ENTRY PER LINE                   05900057
         GBLA  &LNO(63)            NUMBER OF LINES PER GROUP            06000057
.*                                 (ONE ENTRY PER LINEGRP)              06100057
         GBLA  &UNO(63)            NO. OF UNITS PER BUFFER              06200057
.*                                 (ONE ENTRY PER LINEGRP)              06300057
         GBLA  &INT(63)            POLLING INTERVAL                     06400057
.*                                 (ONE ENTRY PER LINEGRP)              06500057
         GBLB  &DIALSW(63)         NETWORK TYPE INDICATORS              06600057
.*                                 (ONE ENTRY PER LINEGRP)              06700057
         GBLC  &T(63)              TERMINAL TYPE                        06800057
.*                                 (ONE ENTRY PER LINEGRP)              06900057
         GBLC  &DDNME(63)          DDNAMES OF LINE GROUPS               07000057
.*                                 (ONE ENTRY PER LINEGRP)              07100057
         GBLB  &FETAB(189)         FEATURES PRESENT INDICATORS          07200057
.*                                 (THREE ENTRIES PER LINEGRP)          07300057
         GBLC  &TTAB(252)          TRANSLATION TABLES                   07400057
.*                                 (FOUR ENTRIES PER LINEGRP)           07500057
         GBLC  &CTAB(252)          CODE SELECTION CHAR SEQUENCES        07600057
.*                                 (FOUR ENTRIES PER LINEGRP)           07700057
         GBLA  &SCRH(2500)         SCREEN HEIGHT                        07800057
.*                                 (ONE ENTRY PER LINE)                 07900057
         GBLA  &SCRW(2500)         SCREEN WIDTH                         08000057
.*                                 (ONE ENTRY PER LINE)                 08100057
         GBLA  &TRMNO(2500)        NO. OF TERMINALS PER LINE            08200057
.*                                 (ONE ENTRY PER LINE)                 08300057
         GBLC  &ADCHAR(2500)       ADDRESSING CHARACTERS                08400057
.*                                 (ONE ENTRY PER TERMINAL)             08500057
         GBLC  &PC(63)             PCI SPECIFICATIONS           SA59163 08600057
.*                                 (ONE ENTRY PER LINE GROUP)   SA59163 08700057
.*                                                                      08800057
.*       LOCAL VARIABLES                                                08900057
.*                                                                      09000057
         LCLA  &OLTST              NO. OF ON-LINE TEST PROCEDURES       09100057
         LCLC  &CRSREF             INDICATES CROSSRF OPTION DESIRED     09200057
         LCLB  &PROMPT             ON MEANS PROMPT USER FOR TCAM PARMS  09300057
         LCLA  &TRCNO              NO. OF TRACE TABLE ENTRIES WANTED    09400057
         LCLA  &DTRCNO             NO. OF DISPATCHER TRACE TBL ENTRIES  09500057
         LCLA  &LNUNNO             NO. OF BASIC UNITS IN BUFFER POOL    09600057
         LCLA  &UNSIZ              SIZE OF TCAM BASIC UNIT              09700057
         LCLB  &CPIDSW             ON MEANS CPU.ID. CONSTANT NEEDED     09800057
         LCLA  &I                  WORK VARIABLE                        09900057
         LCLA  &J                  WORK VARIABLE                        10000057
         LCLA  &K                  WORK VARIABLE                        10100057
         LCLA  &L                  WORK VARIABLE                        10200057
         LCLA  &M                  WORK VARIABLE                        10300057
         LCLA  &N                  WORK VARIABLE                        10400057
         LCLA  &MM                 WORK VARIABLE                        10500057
         LCLA  &P                  WORK VARIABLE                SA65439 10600057
         LCLA  &Q                  WORK VARIABLE                        10700057
         LCLC  &X                  WORK VARIABLE                        10800057
         LCLC  &Y                  WORK VARIABLE                        10900057
         LCLA  &Z                  WORK VARIABLE                        11000057
         LCLC  &EOT                CONTAINS EOT CHARACTER               11100057
         LCLC  &TBL(32)            3270 POLLING/ADDRESSING CHARACTERS   11200057
.*                                 LOOKUP TABLE. THE TABLE HAS 32       11300057
.*                                 ENTRIES. EACH ENTRY HAS 4 ELEMENTS.  11400057
.*                                 EACH ELEMENT HAS TWO CHARACTERS.     11500057
.*                                 1. POLLING CHARACTERS (EBCDIC)       11600057
.*                                 2. CORRESSPONDING ADDRESSING CHARS.  11700057
.*                                 3. POLLING CHARACTERS (ASCII)        11800057
.*                                 4. CORRESPONDING ADDRESSING CHARS.   11900057
         LCLC  &QBYP               CONTAINS QBY PARAMETER               12000057
         LCLC  &L2741(4)           2741 TRANSLATE TABLE ARRAY           12100057
         LCLC  &L1050(4)           1050 TRANSLATE TABLE ARRAY           12200057
         LCLA  &N2741              2741 TRANSLATE TABLE ARRAY COUNTER   12300057
         LCLA  &N1050              1050 TRANSLATE TABLE ARRAY COUNTER   12400057
         LCLC  &FEAT(3)            CONTAINS FEATURE DESCRIPTORS         12500057
         LCLC  &TNAME              TEMP HOLD AREA FOR CHAR EXPRESSION   12600057
         LCLA  &TN                 COUNTER OF TERMINAL/LINE MACRO NAMES 12700057
         LCLA  &IN                 COUNTER FOR INVLIST MACRO NAMES      12800057
         LCLC  &CM(3)              SUBLIST SEPARATORS, COMMAS OR NULLS  12900057
         LCLC  &CS(36)             WILL CONTAIN ALPHAMERIC CHAR SET     13000057
.*                                 (26 ALPHABETIC, 10 NUMERIC)          13100057
         LCLC  &CP(3)              CONTINUATION POSITIONERS -- THESE    13200057
.*                                 ARE SET TO EITHER '' OR '     '.     13300057
.*                                 THEIR FUNCTION IS TO TAKE UP THE     13400057
.*                                 RIGHT AMOUNT OF SPACE IN THE PUNCHED 13500057
.*                                 SOURCE STATEMENTS SUCH THAT THERE    13600057
.*                                 WILL BE A CONTINUATION CHAR IN       13700057
.*                                 COLUMN 72.                           13800057
.*                                                                      13900057
         ACTR  (&NLG+1)*4096       ADJUST ACTR                          14000057
.*                                                                      14100057
.*       INITIALIZE ALPHAMERIC CHARACTER SET ARRAY                      14200057
.*                                                                      14300057
&CS(1)   SETC  'A'                                                      14400057
&CS(2)   SETC  'B'                                                      14500057
&CS(3)   SETC  'C'                                                      14600057
&CS(4)   SETC  'D'                                                      14700057
&CS(5)   SETC  'E'                                                      14800057
&CS(6)   SETC  'F'                                                      14900057
&CS(7)   SETC  'G'                                                      15000057
&CS(8)   SETC  'H'                                                      15100057
&CS(9)   SETC  'I'                                                      15200057
&CS(10)  SETC  'J'                                                      15300057
&CS(11)  SETC  'K'                                                      15400057
&CS(12)  SETC  'L'                                                      15500057
&CS(13)  SETC  'M'                                                      15600057
&CS(14)  SETC  'N'                                                      15700057
&CS(15)  SETC  'O'                                                      15800057
&CS(16)  SETC  'P'                                                      15900057
&CS(17)  SETC  'Q'                                                      16000057
&CS(18)  SETC  'R'                                                      16100057
&CS(19)  SETC  'S'                                                      16200057
&CS(20)  SETC  'T'                                                      16300057
&CS(21)  SETC  'U'                                                      16400057
&CS(22)  SETC  'V'                                                      16500057
&CS(23)  SETC  'W'                                                      16600057
&CS(24)  SETC  'X'                                                      16700057
&CS(25)  SETC  'Y'                                                      16800057
&CS(26)  SETC  'Z'                                                      16900057
&CS(27)  SETC  '0'                                                      17000057
&CS(28)  SETC  '1'                                                      17100057
&CS(29)  SETC  '2'                                                      17200057
&CS(30)  SETC  '3'                                                      17300057
&CS(31)  SETC  '4'                                                      17400057
&CS(32)  SETC  '5'                                                      17500057
&CS(33)  SETC  '6'                                                      17600057
&CS(34)  SETC  '7'                                                      17700057
&CS(35)  SETC  '8'                                                      17800057
&CS(36)  SETC  '9'                                                      17900057
.*                                                                      18000057
.*       INITIALIZE 3270 POLLING/ADDRESSING CHARACTER LOOK-UP TABLE     18100057
.*                                                                      18200057
&TBL(1)  SETC  '4060202D'                                               18300057
&TBL(2)  SETC  'C161412F'                                               18400057
&TBL(3)  SETC  'C2E24253'                                               18500057
&TBL(4)  SETC  'C3E34354'                                               18600057
&TBL(5)  SETC  'C4E44455'                                               18700057
&TBL(6)  SETC  'C5E54556'                                               18800057
&TBL(7)  SETC  'C6E64657'                                               18900057
&TBL(8)  SETC  'C7E74758'                                               19000057
&TBL(9)  SETC  'C8E84859'                                               19100057
&TBL(10) SETC  'C9E9495A'                                               19200057
&TBL(11) SETC  '4A6A5B5C'                                               19300057
&TBL(12) SETC  '4B6B2E2C'                                               19400057
&TBL(13) SETC  '4C6C3C25'                                               19500057
&TBL(14) SETC  '4D6D285F'                                               19600057
&TBL(15) SETC  '4E6E2B3E'                                               19700057
&TBL(16) SETC  '4F6F213F'                                               19800057
&TBL(17) SETC  '50F02630'                                               19900057
&TBL(18) SETC  'D1F14A31'                                               20000057
&TBL(19) SETC  'D2F24B32'                                               20100057
&TBL(20) SETC  'D3F34C33'                                               20200057
&TBL(21) SETC  'D4F44D34'                                               20300057
&TBL(22) SETC  'D5F54E35'                                               20400057
&TBL(23) SETC  'D6F64F36'                                               20500057
&TBL(24) SETC  'D7F75037'                                               20600057
&TBL(25) SETC  'D8F85138'                                               20700057
&TBL(26) SETC  'D9F95239'                                               20800057
&TBL(27) SETC  '5A7A5D3A'                                               20900057
&TBL(28) SETC  '5B7B2423'                                               21000057
&TBL(29) SETC  '5C7C2A40'                                               21100057
&TBL(30) SETC  '5D7D2927'                                               21200057
&TBL(31) SETC  '5E7E3B3D'                                               21300057
&TBL(32) SETC  '5F7F5E22'                                               21400057
.*                                                                      21500057
.*       CHECK FOR MULTIPLE TSOMCP MACRO CALLS                          21600057
.*                                                                      21700057
         AIF   (NOT &MCPSW).SETMCP                                      21800057
         MNOTE 16,'IKJ54125I MORE THAN ONE TSOMCP MACRO CALL ISSUED'    21900057
         MEXIT                                                          22000057
.SETMCP  ANOP                                                           22100057
&MCPSW   SETB  1                   INDICATE A TSOMCP MACRO CALL ISSUED  22200057
.*                                                                      22300057
.*       TEST FOR LINEGRP MACRO CALL HAVING BEEN ISSUED                 22400057
.*                                                                      22500057
         AIF   (&NLG GT 0).LGISUD                                       22600057
         MNOTE 16,'IKJ54126I NO LINEGRP MACRO ISSUED BEFORE TSOMCP MACRO22700057
               O'                                                       22800057
         MEXIT                                                          22900057
.LGISUD  ANOP                                                           23000057
.*                                                                      23100057
.*       CHECK PARAMETER VALIDITY                                       23200057
.*                                                                      23300057
&OLTST   SETA  &OLTEST             NO. OF ON-LINE TEST PROCEDURES       23400057
         AIF   (&OLTST EQ 0).CHKXREF                                    23500057
         AIF   (&OLTST LE 255 AND &OLTST GE 10).CHKXREF                 23600057
         MNOTE 4,'IKJ54110I OLTEST OPERAND OUT OF RANGE, DEFAULT USED'  23700057
&OLTST   SETA  0                        SET DEFAULT                     23800057
.CHKXREF ANOP                                                           23900057
&CRSREF  SETC  '0'                 SET DEFAULT                          24000057
         AIF   ('&OPTIONS' EQ '').CKTR                                  24100057
&I       SETA  0                   INITIALIZE SUB-OPERAND SELECTOR      24200057
.OPLOOP  ANOP                                                           24300057
&I       SETA  &I+1                BUMP SUB-OPERAND SELECTOR            24400057
         AIF   (&I GT N'&OPTIONS).CKTR  BR IF ALL OPTIONS SCANNED       24500057
         AIF   ('&OPTIONS(&I)' EQ 'XREF').SETCR                         24600057
         AIF   ('&OPTIONS(&I)' EQ 'PROMPT').SETPR                       24700057
         MNOTE 4,'IKJ54104I &OPTIONS(&I) INVALID FOR OPTIONS OPERAND'   24800057
         AGO   .OPLOOP             CONTINUE SCANNING                    24900057
.SETCR   ANOP                                                           25000057
&N       SETA  &ADRPT-1            SET TERMINAL COUNT                   25100057
&M       SETA  0                   SET LOOP VARIABLE                    25200057
.XREFLOP ANOP                      LOOP ONCE/LINE IN LAST L.G.          25300057
&N       SETA  &N+&TRMNO(&SCRPT+&M)  UPDATE TERMINAL COUNT              25400057
&M       SETA  &M+1                BUMP LOOP CONTROL VARIABLE           25500057
         AIF   (&M LT &LNO(&NLG)).XREFLOP  BR IF MORE LINES             25600057
&CRSREF  SETC  '&N'                SET NO. OF XREF ENTRIES              25700057
         AGO   .OPLOOP             CONTINUE SCANNING                    25800057
.SETPR   ANOP                                                           25900057
&PROMPT  SETB  1                   INDICATE PROMPT REQUESTED            26000057
         AGO   .OPLOOP             CONTINUE SCANNING                    26100057
.CKTR    ANOP                                                           26200057
&TRCNO   SETA  &TRACE                                                   26300057
         AIF   (&TRCNO LE 65535).CKDTR                                  26400057
         MNOTE 4,'IKJ54110I TRACE OPERAND OUT OF RANGE, DEFAULT USED'   26500057
&TRCNO   SETA  0                                                        26600057
.CKDTR   ANOP                                                           26700057
&DTRCNO  SETA  &DTRACE                                                  26800057
         AIF   (&DTRCNO LE 65535).CKLN                                  26900057
         MNOTE 4,'IKJ54110I DTRACE OPERAND OUT OF RANGE, DEFAULT USED'  27000057
&DTRCNO  SETA  0                                                        27100057
.CKLN    ANOP                                                           27200057
         AIF   ('&LNUNITS' EQ '').LNUDEF  CHK IF DEFAULT VALUE WANTED   27300057
&LNUNNO  SETA  &LNUNITS                                                 27400057
         AIF   (&LNUNNO GT 65535).BADLNU                                27500057
         AIF   (&LNUNNO GT 0).CKUN                                      27600057
.BADLNU  MNOTE 4,'IKJ54110I LNUNITS OPERAND OUT OF RANGE, DEFAULT USED' 27700057
.*                                                                      27800057
.*       THE FOLLOWING ROUTINE COMPUTES THE DEFAULT VALUE FOR LNUNITS   27900057
.*       USING THE PARAMETERS SUPPLIED IN PREVIOUS LINEGRP MACRO CALLS  28000057
.*                                                                      28100057
.LNUDEF  ANOP                                                           28200057
&I       SETA  1                   SET LOOP INDEX                       28300057
&LNUNNO  SETA  0                                                        28400057
.LNULOOP ANOP                                                           28500057
         AIF   (&I GT &NLG).TRUNC  BR IF ALL LINE GROUPS TALLIED        28600057
&K       SETA  20                  ASSUME 2 BUFFERS/TERMINAL            28700057
         AIF   ('&T(&I)' EQ '').LNULOP2  DON'T CHK NULL STRING          28800057
         AIF   ('&T(&I)'(1,3) EQ '327').DSPLY                           28900057
         AIF   ('&T(&I)'(1,3) NE '226').LNULOP2                         29000057
.DSPLY   ANOP                                                           29100057
&K       SETA  25                  ASSUME 2.5 BFRS/TERM FOR 2260/65     29200057
.*                                 AND FOR 3270                         29300057
.LNULOP2 ANOP                                                           29400057
&LNUNNO  SETA  &LNUNNO+&K*&LNO(&I)*&UNO(&I)                             29500057
&I       SETA  &I+1                                                     29600057
         AGO   .LNULOOP                                                 29700057
.TRUNC   ANOP                                                           29800057
&LNUNNO  SETA  (&LNUNNO+5)/10      ROUND & TRUNCATE                     29900057
.CKUN    ANOP                                                           30000057
&UNSIZ   SETA  &UNITSIZ                                                 30100057
         AIF   (&UNSIZ LT 41).BADUNS                                    30200057
         AIF   (&UNSIZ LE 255).GOTEST                                   30300057
.BADUNS  MNOTE 4,'IKJ54110I UNITSIZ OPERAND OUT OF RANGE, DEFAULT USED' 30400057
&UNSIZ   SETA  60                       SET DEFAULT BASIC UNIT SIZE     30500057
.GOTEST  ANOP                                                           30600057
.*                                                                      30700057
.*       TEST FOR SERIOUS ERRORS IN PREVIOUS MACROS                     30800057
.*                                                                      30900057
.TSTQUIT AIF   (NOT &QUITSW).INTRO                                      31000057
         MNOTE 16,'IKJ54127I SERIOUS ERROR IN PREVIOUS MACRO CALL PREVEN31100057
               NTS FURTHER GENERATION'                                  31200057
         MEXIT                                                          31300057
.*                                                                      31400057
.*********************************************************************  31500057
.*       INTRO                                                          31600057
.*********************************************************************  31700057
.*                                                                      31800057
.INTRO   ANOP                                                           31900057
 PUNCH '&NAM CSECT'                                                     32000057
 PUNCH '         INTRO ENVIRON=TSO,KEYLEN=&UNSIZ,LNUNITS=&LNUNNO,CIB=2,-32100057
                ...................'                                    32200057
&X       SETC  'STSP'              ASSUME START/STOP LINE               32300057
         AIF   (NOT &BISYNC).LINE2                                      32400057
&X       SETC  'BOTH'              SET LINETYPE TO BOTH FOR BISYNC LINE 32500057
.LINE2   ANOP                                                           32600057
 PUNCH '               CROSSRF=&CRSREF,TRACE=&TRCNO,LINETYP=&X,        -32700057
                        .........'                             @OZ16602 32800057
.*                                                                      32900057
         AIF   (NOT &PROMPT).NOPRMPT  BR IF NO PROMPT DESIRED           33000057
 PUNCH '               DTRACE=&DTRCNO,OLTEST=&OLTST,PROGID=&NAM'        33100057
         AGO   .OPEN                                                    33200057
.NOPRMPT ANOP                                                           33300057
 PUNCH '               DTRACE=&DTRCNO,STARTUP=C,OLTEST=&OLTST,PROGID=&N-33400057
               AM'                                                      33500057
.OPEN    ANOP                                                           33600057
 PUNCH '         LTR   15,15'                                           33700057
 PUNCH '         BNZ   IEDAYBYE'                                        33800057
.*                                                                      33900057
.*********************************************************************  34000057
.*       OPEN'S                                                         34100057
.*********************************************************************  34200057
.*                                                                      34300057
 PUNCH '         LA    3,DCBL1'                                         34400057
 PUNCH '         LA    4,DCBL2-DCBL1'                                   34500057
 PUNCH '         LA    5,DCBLAST'                                       34600057
 PUNCH '         SR    7,7'                                     YM2220  34700057
 PUNCH 'OPENLOOP LR    1,3'                                             34800057
 PUNCH '         OPEN  MF=(E,(1))'                                      34900057
 PUNCH '         USING IHADCB,6'                                        35000057
 PUNCH '         L     6,0(,3)'                                         35100057
 PUNCH '         TM    DCBOFLGS,DCBOFOPN'                               35200057
 PUNCH '         BO    OPNLTST'                                         35300057
 PUNCH '         MVC   OPENWTO+34(8),DCBDDNAM'                          35400057
 PUNCH 'OPENWTO  WTO   ''IKJ403I LINE GROUP FOR DD          NOT OPENED'-35500057
               ',DESC=6, -'                                             35600057
 PUNCH '               ROUTCDE=2'                                       35700057
 PUNCH '         B     OPENNEXT'                                 YM2220 35800057
 PUNCH 'OPNLTST  BALR  7,0'                                      YM2220 35900057
 PUNCH 'OPENNEXT BXLE  3,4,OPENLOOP'                             YM2220 36000057
 PUNCH '         DROP  6'                                               36100057
 PUNCH '         B     OPENDONE'                                        36200057
 PUNCH 'DCBL1    DS    0F'                                              36300057
&I       SETA  1                                                        36400057
.OPNLOOP ANOP                                                           36500057
         AIF   (&I EQ &NLG).OPNLAST                                     36600057
 PUNCH '         OPEN  (DCB&I,(INOUT)),MF=L'                            36700057
         AGO   .OPLTST                                                  36800057
.OPNLAST ANOP                                                           36900057
 PUNCH 'DCBLAST  OPEN  (DCB&I,(INOUT)),MF=L'                            37000057
.OPLTST  ANOP                                                           37100057
         AIF   (&I NE 1).OPLTST2                                        37200057
 PUNCH 'DCBL2    EQU   *'                                               37300057
.OPLTST2 ANOP                                                           37400057
&I       SETA  &I+1                                                     37500057
         AIF   (&I LE &NLG).OPNLOOP                                     37600057
 PUNCH 'OPENDONE DS    0H'                                              37700057
 PUNCH '         LTR   7,7'                                      YM2220 37800057
 PUNCH '         BZ    IEDAYBYE'                                 YM2220 37900057
.*                                                                      38000057
.*********************************************************************  38100057
.*       READY                                                          38200057
.*********************************************************************  38300057
.*                                                                      38400057
 PUNCH '         READY'                                                 38500057
.*                                                                      38600057
.*********************************************************************  38700057
.*       CLOSE'S                                                        38800057
.*********************************************************************  38900057
.*                                                                      39000057
&I       SETA  1                                                        39100057
.CLSLOOP ANOP                                                           39200057
 PUNCH '         CLOSE (DCB&I)'                                         39300057
&I       SETA  &I+1                                                     39400057
         AIF   (&I LE &NLG).CLSLOOP                                     39500057
.*                                                                      39600057
.*********************************************************************  39700057
.*       RETURN                                                         39800057
.*********************************************************************  39900057
.*                                                                      40000057
 PUNCH 'IEDAYBYE L     13,4(,13)'                                       40100057
 PUNCH '         RETURN (14,12)'                                        40200057
.*                                                                      40300057
.*********************************************************************  40400057
.*       TTABLE                                                         40500057
.*********************************************************************  40600057
.*                                                                      40700057
 PUNCH '         TTABLE LAST=TLAST,MAXLEN=5'                            40800057
.*                                                                      40900057
.*********************************************************************  41000057
.*       OPTION                                                         41100057
.*********************************************************************  41200057
.*                                                                      41300057
 PUNCH 'OPNAME   OPTION A'                                     @SA73586 41400057
.*                                                                      41500057
.*********************************************************************  41600057
.*       TERMINAL'S                                                     41700057
.*********************************************************************  41800057
.*                                                                      41900057
&SCRPT   SETA  1                   INITIALIZE SCREEN ARRAY POINTER      42000057
&TN      SETA  1000                INITIALIZE MACRO COUNTER             42100057
&I       SETA  1                   SET OUTER LOOP CONTROL               42200057
.TERMLIN ANOP                      LOOP EXECUTED ONCE FOR EACH LINEGRP  42300057
.*                                                                      42400057
.*       BUILD DESCRIPTIVE NAMES OF FEATURES                            42500057
.*                                                                      42600057
&J       SETA  (&I-1)*3            SET FEATUR TABLE OFFSET VALUE        42700057
         AIF   (&FETAB(&J+1)).TL1  TEST PRESENCE OF BREAK FEATURE       42800057
&FEAT(1) SETC  'NOBREAK'                                                42900057
         AGO   .TL2                                                     43000057
.TL1     ANOP                                                           43100057
&FEAT(1) SETC  'BREAK'                                                  43200057
.TL2     AIF   (&FETAB(&J+2)).TL3  TEST PRESENCE OF ATTN FEATURE        43300057
&FEAT(2) SETC  'NOATTN'                                                 43400057
         AGO   .TL4                                                     43500057
.TL3     ANOP                                                           43600057
&FEAT(2) SETC  'ATTN'                                                   43700057
.TL4     AIF   (&FETAB(&J+3)).TL5  TEST PRESENCE OF TOSUPPR FEATURE     43800057
&FEAT(3) SETC  ''                                                       43900057
         AGO   .TL6                                                     44000057
.TL5     ANOP                                                           44100057
&FEAT(3) SETC  ',TOSUPPR'                                               44200057
.TL6     ANOP                                                           44300057
.*                                                                      44400057
.*       BUILD MACRO LABEL                                              44500057
.*                                                                      44600057
&J       SETA  1                   SET INNER LOOP CONTROL VARIABLE      44700057
.TLINLOP ANOP                      LOOP EXECUTED ONCE PER LINE          44800057
         AIF   (&J GT &LNO(&I)).TLOUT BR IF NOT MORE LINES IN GROUP     44900057
&K       SETA  1                   SET INNERMOST LOOP COUNTER           45000057
.TLINMLP ANOP                      LOOP EXECUTED ONCE/TERMINAL ON LINE  45100057
         AIF   (&K GT &TRMNO(&SCRPT)).TL12  BR IF NOT MORE TERM'S       45200057
&TN      SETA  &TN+1               INCREMENT TTABLE ENTRY  COUNT        45300057
         AIF   (&I EQ &NLG AND &J EQ &LNO(&I) AND &K EQ &TRMNO(&SCRPT))-45400057
               .TLAST              BR IF LAST TERMINAL MACRO IN MCP     45500057
&TNAME   SETC  'T&TN'              BUILD TTABLE ENTRY NAME              45600057
         AGO   .TL10                                                    45700057
.TLAST   ANOP                                                           45800057
&TNAME   SETC  'TLAST'             BUILD SPECIAL NAME FOR LAST ENTRY    45900057
.TL10    ANOP                                                           46000057
&CRSREF  SETC  'NO'                ASSUME NON-SWITCHED LINE             46100057
&QBYP    SETC  'QBY=T,'            INCLUDE QBY PARAMETER                46200057
         AIF   (NOT &DIALSW(&I)).LINE                                   46300057
&CRSREF  SETC  'YES'               INDICATE SWITCHED LINE               46400057
&QBYP    SETC  '      '            OMIT QBY PARAMETER                   46500057
.LINE    ANOP                                                           46600057
.*                                                                      46700057
.*       BUILD FIRST LINE OF TERMINAL MACRO                             46800057
.*                                                                      46900057
 PUNCH '&TNAME    TERMINAL &QBYP.DCB=DCB&I,RLN=&J,TERM=&T(&I),QUEUES=TSX47000057
               ,        .........'                                      47100057
.*                                                                      47200057
.*       PUNCH SECOND LINE OF TERMINAL MACRO                            47300057
.*                                                                      47400057
         AIF   ('&TTAB((&I-1)*4+2)' EQ '').TNDYTRN  BR ON NOT DYNAMIC   47500057
&TNAME   SETC  'OPDATA=0'          INCLUDE OPDATA PARAMETER             47600057
&CM(1)   SETC  ','                 COMMA NEEDED WITH OPDATA PARM        47700057
         AGO   .TSCRN              GO CHK SCREEN                        47800057
.TNDYTRN ANOP                      NOT DYNAMIC TRANSLATION              47900057
&TNAME   SETC  '        '          DON'T INCLUDE OPDATA PARAMETER       48000057
&CM(1)   SETC  ' '                 NO COMMA NEEDED -- NO OPDATA PARM    48100057
.TSCRN   ANOP                                                           48200057
         AIF   (&SCRH(&SCRPT) EQ 0 AND &SCRW(&SCRPT) EQ 0).TNOSCR       48300057
 PUNCH '               UTERM=&CRSREF,SCRSIZE=(&SCRH(&SCRPT),&SCRW(&SCRPX48400057
               T)),&TNAME&CM(1)                 .........'              48500057
         AGO   .TPUN3              GO PUNCH 3RD LINE                    48600057
.TNOSCR  ANOP                                                           48700057
 PUNCH '               UTERM=&CRSREF,&TNAME&CM(1)                      X48800057
                           ........'                                    48900057
.TPUN3   ANOP                                                           49000057
.*                                                                      49100057
.*       PUNCH THIRD LINE OF TERMINAL MACRO                             49200057
.*                                                                      49300057
&Y       SETC  ''                                                       49400057
         AIF   ('&ADCHAR(&TN-1000)' EQ '').TLNOAD  TEST FOR NULL ADDR   49500057
&X       SETC  '&ADCHAR(&TN-1000)' ASSUME NOT 1050 OR 226R/5 OR 327R    49600057
         AIF   ('&T(&I)' EQ '327R' OR '&T(&I)' EQ '327S').T3270         49700057
         AIF   ('&T(&I)' NE '226R' AND '&T(&I)' NE '2265').T1050        49800057
&X       SETC  '&X'(1,4)'A0'                                            49900057
         AGO   .TLPAST                                                  50000057
.T3270   ANOP                                                           50100057
&Z       SETA  1                        INITIALIZE PTR FOR TABLE LOOKUP 50200057
         AIF   ('&TTAB((&I-1)*4+1)' EQ 'ASCI').ASCI CHECK TRANTAB       50300057
.EBCD    ANOP                                                           50400057
&Q       SETA  1                        POSITION IN TABLE ELEMENT       50500057
&Y       SETC  '2D'                                                     50600057
         AGO   .SEARCH                                                  50700057
.ASCI    ANOP                                                           50800057
&Q       SETA  5                        POSITION IN TABLE ELEMENT       50900057
&Y       SETC  '05'                                                     51000057
.SEARCH  ANOP                                                           51100057
         AIF   ('&X'(1,2) EQ '&TBL(&Z)'(&Q,2)).FOUND                    51200057
&Z       SETA  &Z+1                     POINTS AT NEXT ENTRY            51300057
         AIF   (&Z LE 32).SEARCH                                        51400057
         MNOTE 8,'IKJ54128I ADDRESSING CHARACTERS INVALID OR MISSING FOX51500057
               R TERMINAL IN LINE GROUP &I'                             51600057
&X       SETC  '        '                                               51700057
         AGO   .TLPAST                                                  51800057
.FOUND   ANOP                                                           51900057
&X       SETC  '&TBL(&Z)'(&Q+2,2)'&TBL(&Z)'(&Q+2,2)'&X'(3,2)'&X'(3,2)   52000057
.*                                      REPLICATING ADD. CHARS.@OS78355 52100057
         AGO   .TLPAST                                                  52200057
.T1050   ANOP                                                           52300057
         AIF   ('&T(&I)' NE '1050' AND '&T(&I)' NE '5041').TLPAST       52400057
&X       SETC  '&X'(1,2)'13'       ADD COMPONENT SELECTOR               52500057
.TLPAST  ANOP                                                           52600057
 PUNCH '               ADDR=&X&Y,FEATURE=(&FEAT(1),&FEAT(2)&FEAT(3))'   52700057
         AGO   .TL11                                                    52800057
.TLNOAD  ANOP                                                           52900057
         AIF   ('&T(&I)'(1,3) NE '226' AND '&T(&I)'(1,3) NE '327' AND '&53000057
               &T(&I)' NE '1050').TLPNOAD                               53100057
         AIF   ('&T(&I)' EQ '327L').TLPNOAD                             53200057
         AIF   ('&T(&I)' EQ '226L').TLPNOAD                             53300057
         MNOTE 8,'IKJ54128I ADDRESSING CHARACTERS INVALID OR MISSING FOX53400057
               R TERMINAL IN LINE GROUP &I'                             53500057
.TLPNOAD ANOP                                                           53600057
 PUNCH '               FEATURE=(&FEAT(1),&FEAT(2)&FEAT(3))'             53700057
.TL11    ANOP                                                           53800057
&K       SETA  &K+1                BUMP INNERMOST LOOP COUNTER          53900057
         AGO   .TLINMLP            GO TO INNERMOST LOOP TEST            54000057
.TL12    ANOP                                                           54100057
&SCRPT   SETA  &SCRPT+1            BUMP SCREEN ARRAY POINTER            54200057
&J       SETA  &J+1                INCREMENT INNER LOOP COUNTER         54300057
         AGO   .TLINLOP            GO TEST FOR MORE LINES IN GROUP      54400057
.*       OUTER LOOP TEST                                                54500057
.TLOUT   ANOP                                                           54600057
&I       SETA  &I+1                INCREMENT OUTER LOOP INDEX           54700057
         AIF   (&I LE &NLG).TERMLIN  BR IF MORE LINE GROUPS             54800057
.*                                                                      54900057
.*********************************************************************  55000057
.*       TSINPUT                                                        55100057
.*********************************************************************  55200057
.*                                                                      55300057
 PUNCH '         TSINPUT'                                               55400057
.*                                                                      55500057
.*********************************************************************  55600057
.*       DCB'S                                                          55700057
.*********************************************************************  55800057
.*                                                                      55900057
&IN      SETA  0                   INITIALIZE INVLIST COUNTER           56000057
&I       SETA  1                   SET LOOP CONTROL VARIABLE            56100057
.DCBLOOP ANOP                      LOOP EXECUTED ONCE FOR EACH LINEGRP  56200057
&J       SETA  1                   ASSUME BUFIN=1                       56300057
&P       SETA  2                   ASSUME BUFOUT=2              SA65439 56400057
         AIF   ('&T(&I)'(1,3) NE '226' AND '&T(&I)'(1,3) NE '327').PUNDX56500057
               CB                                                       56600057
&J       SETA  2                   BUFIN=2 FOR 2260/65 AND FOR 3270     56700057
         AIF   ('&T(&I)'(1,3) NE '327').PUNDCB                  SA65439 56800057
&P       SETA  3                   BUFOUT=3 FOR 3270            SA65439 56900057
.PUNDCB  ANOP                                                           57000057
 PUNCH 'DCB&I    DCB   DSORG=TX,MACRF=(G,P),INTVL=&INT(&I),CPRI=S, ....X57100057
               ...................'                                     57200057
 PUNCH '               DDNAME=&DDNME(&I),BUFIN=&J,BUFOUT=&P,MH=TSOMH, .X57300057
               ...................'                             SA65439 57400057
&X       SETC  '&TTAB((&I-1)*4+1)'  SET SCT TABLE NAME                  57500057
&K       SETA  &UNSIZ*&UNO(&I)     COMPUTE BUFFER SIZE                  57600057
&J       SETA  &J+1                COMPUTE BUFMAX                       57700057
         AIF   ('&TTAB((&I-1)*4+2)' EQ '').DB1 BR IF ONLY 1 TRAN TBL    57800057
&TNAME   SETC  'TL&I'              BUILD NAME OF TRANSLIST              57900057
         AIF   ('&T(&I)' NE '5041').DB2   BR IF NOT 5041 LINE GROUP     58000057
&X       SETC  '1050'              1050 IS SCT FOR 5041 LINE GROUPS     58100057
         AGO   .DB2                                                     58200057
.DB1     ANOP                                                           58300057
&TNAME   SETC  '&TTAB((&I-1)*4+1)' GET NAME OF TRANSLATE TABLE          58400057
.DB2     ANOP                                                           58500057
 PUNCH '               BUFSIZE=&K,BUFMAX=&J,PCI=&PC(&I),TRANS=&TNAME, .X58600057
               ...............'                                 SA59163 58700057
&IN      SETA  &IN+1               BUMP INVLIST COUNTER                 58800057
.*                                                                      58900057
.*       BRANCH IF SEVERAL INVLIST SUB-OPERANDS                         59000057
         AIF   (&LNO(&I) GT 1).DB3                                      59100057
.*                                                                      59200057
.*       COMPUTE VALUES FOR SELECTION OF CHARACTERS IN THE              59300057
.*       ALPHAMERIC CHARACTER SET ARRAY.  THESE TWO SELECTED CHARACTERS 59400057
.*       WILL BE CONCATENATED TO FORM THE INVLIST MACRO NAME.           59500057
&L       SETA  (&IN-1)/36+1        SET 1ST CHARACTER SELECTOR           59600057
&M       SETA  &IN-(&L-1)*36       SET 2ND CHAR SELECTOR                59700057
 PUNCH '               SCT=&X,INVLIST=(&CS(&L)&CS(&M))'                 59800057
         AGO   .DCBTEST            GO TEST FOR MORE LINE GROUPS         59900057
.DB3     ANOP                                                           60000057
&L       SETA  (&IN-1)/36+1        SET 1ST CHARACTER SELECTOR           60100057
&M       SETA  &IN-(&L-1)*36       SET 2ND CHAR SELECTOR                60200057
 PUNCH '               SCT=&X,INVLIST=(&CS(&L)&CS(&M),,,               X60300057
                             .........'                                 60400057
.*                                                                      60500057
.*       SET UP LOOP TO GENERATE REST OF INVLIST SUB-OPERANDS           60600057
.*                                                                      60700057
&J       SETA  2                   INITIALIZE LINE COUNTER              60800057
.DCBINLP ANOP                                                           60900057
&IN      SETA  &IN+1               BUMP INVLIST COUNTER                 61000057
.*       BRANCH IF LAST SUB-OPERAND COMING UP NEXT                      61100057
         AIF   (&J EQ &LNO(&I)).DB4                                     61200057
.*                                                                      61300057
.*       COMPUTE VALUES FOR SELECTION OF CHARACTERS IN THE              61400057
.*       ALPHAMERIC CHARACTER SET ARRAY.  THESE TWO SELECTED CHARACTERS 61500057
.*       WILL BE CONCATENATED TO FORM THE INVLIST MACRO NAME.           61600057
&L       SETA  (&IN-1)/36+1        SET 1ST CHARACTER SELECTOR           61700057
&M       SETA  &IN-(&L-1)*36       SET 2ND CHAR SELECTOR                61800057
 PUNCH '               &CS(&L)&CS(&M),,,                               X61900057
                                   X'                                   62000057
&J       SETA  &J+1                BUMP LINE COUNTER                    62100057
         AGO   .DCBINLP                                                 62200057
.DB4     ANOP                                                           62300057
&L       SETA  (&IN-1)/36+1        SET 1ST CHARACTER SELECTOR           62400057
&M       SETA  &IN-(&L-1)*36       SET 2ND CHAR SELECTOR                62500057
 PUNCH '               &CS(&L)&CS(&M))' PUNCH LAST SUBOPERAND           62600057
.*                                                                      62700057
.*       DCB GENERATION LOOP TEST                                       62800057
.*                                                                      62900057
.DCBTEST ANOP                                                           63000057
&I       SETA  &I+1                INCREMENT LOOP CONTROL VARIABLE      63100057
         AIF   (&I LE &NLG).DCBLOOP BR IF MORE LINE GROUPS              63200057
.*                                                                      63300057
.*********************************************************************  63400057
.*       TRANLIST'S                                                     63500057
.*********************************************************************  63600057
.*                                                                      63700057
&I       SETA  1                   SET OUTER LOOP INDEX VARIABLE        63800057
.TRLOOP  ANOP                      LOOP EXECUTED ONCE FOR EACH LINEGRP  63900057
&J       SETA  (&I-1)*4+1          PT TO 1ST OF GROUP IN &TTAB, &CTAB   64000057
         AIF   ('&TTAB(&J+1)' EQ '').TRLPTST BE IF TRANLIST UNNECESSARY 64100057
.*                                                                      64200057
.*       THIS ROUTINE SCANS THE TRANSLATE TABLE NAMES OF A LINEGRP      64300057
.*       LOOKING FOR 2741 OR 1050 TABLES.  WHEN (AND IF) FOUND THEY ARE 64400057
.*       PLACED IN  ARRAYS  FROM WHICH THE L2741= AND L1050=            64500057
.*       PARAMETERS WILL LATER BE GENERATED IF BOTH 2740'S AND 1050'S   64600057
.*       ARE INVOLVED IN THE LINE GROUP.                                64700057
.*                                                                      64800057
&L2741(1) SETC  ''                 INITIALIZE ARRAYS                    64900057
&L2741(2) SETC  ''                                                      65000057
&L2741(3) SETC  ''                                                      65100057
&L2741(4) SETC  ''                                                      65200057
&L1050(1) SETC  ''                                                      65300057
&L1050(2) SETC  ''                                                      65400057
&L1050(3) SETC  ''                                                      65500057
&L1050(4) SETC  ''                                                      65600057
&N2741   SETA  0                   INITIALIZE ARRAY COUNTERS            65700057
&N1050   SETA  0                                                        65800057
&K       SETA  0                   SET LOOP CONTROL VARIABLE            65900057
.*       SKIP NULL TABLE ENTRIES                                        66000057
.TRLP2   AIF   ('&TTAB(&J+&K)' EQ '').TRLP2T                            66100057
         AIF   ('&TTAB(&J+&K)'(3,2) NE '41').TRLP3                      66200057
&N2741   SETA  &N2741+1                                                 66300057
&L2741(&N2741) SETC '&TTAB(&J+&K)'                                      66400057
         AGO   .TRLP2T             GO TO SCANNING LOOP TEST             66500057
.TRLP3   AIF   ('&TTAB(&J+&K)'(3,2) NE '50').TRLP2T                     66600057
&N1050   SETA  &N1050+1                                                 66700057
&L1050(&N1050) SETC '&TTAB(&J+&K)'                                      66800057
.TRLP2T  ANOP                                                           66900057
&K       SETA  &K+1                                                     67000057
         AIF   (&K LE 3).TRLP2     BR UNTIL ALL TBL NAMES ARE CHECKED   67100057
         AIF   (&N2741 NE 0 AND &N1050 NE 0).TRLBOTH                    67200057
.*                                                                      67300057
.*       THIS ROUTINE IS EXECUTED UNLESS THE LINE GROUP HAS BOTH        67400057
.*       2740 AND 1050 TERMINALS.  THIS ROUTINE GENERATES THE           67500057
.*       LIST= PARAMETER.                                               67600057
.*                                                                      67700057
&CM(2)   SETC  ''                  INITIALIZE SUBLIST SEPARATORS        67800057
&CM(3)   SETC  ''                                                       67900057
&CP(2)   SETC  '     '             INITIALIZE CONTINUATION POSITIONERS  68000057
&CP(3)   SETC  '     '                                                  68100057
.*       MAKE SUBLIST SEPARATORS COMMAS IF THERE ARE, IN FACT,          68200057
.*       OPERANDS TO SEPARATE.  ALSO SET THE CONTINUATION POSITIONERS   68300057
.*       TO THE PROPER LENGTH SO THAT A CONTINUATION CHARACTER WILL     68400057
.*       APPEAR IN COLUMN 72.                                           68500057
         AIF   ('&TTAB(&J+2)' EQ '').TRL1                               68600057
&CM(2)   SETC  ','                                                      68700057
&CP(2)   SETC  ''                                                       68800057
.TRL1    AIF   ('&TTAB(&J+3)' EQ '').TRL2                               68900057
&CM(3)   SETC  ','                                                      69000057
&CP(3)   SETC  ''                                                       69100057
.TRL2    ANOP                                                           69200057
 PUNCH 'TL&I     TRANLIST LIST=(&TTAB(&J),&TTAB(&J+1)&CM(2)&TTAB(&J+2)&X69300057
               CM(3)&TTAB(&J+3)),&CP(2)&CP(3)                 .........X69400057
               ........'                                                69500057
         AGO   .TRLCHAR            GO GENERATE CHARS= PARAMETER         69600057
.*                                                                      69700057
.*       THIS ROUTINE GENERATES THE L2741= PARAMETER                    69800057
.*                                                                      69900057
.TRLBOTH ANOP                                                           70000057
&CM(1)   SETC  ''                  INITIALIZE SUBLIST SEPARATORS        70100057
&CM(2)   SETC  ''                                                       70200057
&CM(3)   SETC  ''                                                       70300057
&CP(1)   SETC  '     '             INITIALIZE CONTINUATION POSITIONERS  70400057
&CP(2)   SETC  '     '                                                  70500057
&CP(3)   SETC  '     '                                                  70600057
.*       MAKE SUBLIST SEPARATORS COMMAS IF THERE ARE, IN FACT,          70700057
.*       OPERANDS TO SEPARATE.  ALSO SET THE CONTINUATION POSITIONERS   70800057
.*       TO THE PROPER LENGTH SO THAT A CONTINUATION CHARACTER WILL     70900057
.*       APPEAR IN COLUMN 72.                                           71000057
         AIF   (&N2741 LT 2).TRL3                                       71100057
&CM(1)   SETC  ','                                                      71200057
&CP(1)   SETC  ''                                                       71300057
         AIF   (&N2741 LT 3).TRL3                                       71400057
&CM(2)   SETC  ','                                                      71500057
&CP(2)   SETC  ''                                                       71600057
         AIF   (&N2741 LT 4).TRL3                                       71700057
&CM(3)   SETC  ','                                                      71800057
&CP(3)   SETC  ''                                                       71900057
.TRL3    ANOP                                                           72000057
 PUNCH 'TL&I     TRANLIST L2741=(&L2741(1)&CM(1)&L2741(2)&CM(2)&L2741(3X72100057
               )&CM(3)&L2741(4)),&CP(1)&CP(2)&CP(3)                 ...X72200057
               .............'                                           72300057
.*                                                                      72400057
.*       THIS ROUTINE GENERATES THE L1050= PARAMETER                    72500057
.*                                                                      72600057
&CM(1)   SETC  ''                  INITIALIZE SUBLIST SEPARATORS        72700057
&CM(2)   SETC  ''                                                       72800057
&CM(3)   SETC  ''                                                       72900057
&CP(1)   SETC  '     '             INITIALIZE CONTINUATION POSITIONERS  73000057
&CP(2)   SETC  '     '                                                  73100057
&CP(3)   SETC  '     '                                                  73200057
.*       MAKE SUBLIST SEPARATORS COMMAS IF THERE ARE, IN FACT,          73300057
.*       OPERANDS TO SEPARATE.  ALSO SET THE CONTINUATION POSITIONERS   73400057
.*       TO THE PROPER LENGTH SO THAT A CONTINUATION CHARACTER WILL     73500057
.*       APPEAR IN COLUMN 72.                                           73600057
         AIF   (&N1050 LT 2).TRL4                                       73700057
&CM(1)   SETC  ','                                                      73800057
&CP(1)   SETC  ''                                                       73900057
         AIF   (&N1050 LT 3).TRL4                                       74000057
&CM(2)   SETC  ','                                                      74100057
&CP(2)   SETC  ''                                                       74200057
         AIF   (&N1050 LT 4).TRL4                                       74300057
&CM(3)   SETC  ','                                                      74400057
&CP(3)   SETC  ''                                                       74500057
.TRL4    ANOP                                                           74600057
 PUNCH '               L1050=(&L1050(1)&CM(1)&L1050(2)&CM(2)&L1050(3)&CX74700057
               M(3)&L1050(4)),&CP(1)&CP(2)&CP(3)                    ...X74800057
               .............'                                           74900057
.*                                                                      75000057
.*       THIS ROUTINE GENERATES THE CHARS= PARAMETERS                   75100057
.*                                                                      75200057
.TRLCHAR ANOP                                                           75300057
&CM(1)   SETC  ''                  INITIALIZE SUBLIST SEPARATORS        75400057
&CM(2)   SETC  ''                                                       75500057
&CM(3)   SETC  ''                                                       75600057
.*       MAKE SUBLIST SEPARATORS COMMAS IF THERE ARE, IN FACT,          75700057
.*       OPERANDS TO SEPARATE                                           75800057
         AIF   ('&CTAB(&J+1)' EQ '').TRL5                               75900057
&CM(1)   SETC  ','                                                      76000057
         AIF   ('&CTAB(&J+2)' EQ '').TRL5                               76100057
&CM(2)   SETC  ','                                                      76200057
         AIF   ('&CTAB(&J+3)' EQ '').TRL5                               76300057
&CM(3)   SETC  ','                                                      76400057
.TRL5    ANOP                                                           76500057
 PUNCH '               CHARS=(&CTAB(&J)&CM(1)&CTAB(&J+1)&CM(2)&CTAB(&J+X76600057
               2)&CM(3)&CTAB(&J+3)),OPFLD=OPNAME'                       76700057
.*                                                                      76800057
.*       TRANLIST LOOP TEST                                             76900057
.*                                                                      77000057
.TRLPTST ANOP                                                           77100057
&I       SETA  &I+1                                                     77200057
         AIF   (&I LE &NLG).TRLOOP BR IF MORE LINE GROUPS TO HANDLE     77300057
.*                                                                      77400057
.*********************************************************************  77500057
.*       INVLIST'S                                                      77600057
.*********************************************************************  77700057
.*                                                                      77800057
&SCRPT   SETA  1                   INITIALIZE TRMNO ARRAY POINTER       77900057
&ADRPT   SETA  0                   INITIALIZE ADCHAR ARRAY POINTER      78000057
&IN      SETA  1                   INITIALIZE INVLIST COUNTER           78100057
&K       SETA  1000                INITIALIZE TTABLE NAME COUNTER       78200057
&I       SETA  1                   SET OUTER LOOP CONTROL VARIABLE      78300057
.IVL1    ANOP                      LOOP EXECUTED ONCE FOR EACH LINEGRP  78400057
&J       SETA  1                   SET INNER LOOP CONTROL VARIABLE      78500057
&EOT     SETC  ''                                                       78600057
.IVL2    ANOP                      LOOP EXECUTED ONCE FOR EACH LINE     78700057
&N       SETA  1                   SET INNERMOST LOOP COUNTER           78800057
.IVL3    ANOP                      LOOP EXECUTED ONCE/TERMINAL ON LINE  78900057
         AIF   (&J GT &LNO(&I)).IVL1T BR IF ALL LINES IN LINEGRP DONE   79000057
         AIF   (&N GT &TRMNO(&SCRPT)).IVL2T  BR IF ALL TERM'S ON LINE   79100057
         AIF   (&N LT &TRMNO(&SCRPT)).IL1  BR IF NOT LAST TERM ON LINE  79200057
         AIF   (&J LT &LNO(&I)).IL1 BR IF NOT LAST LINE IN LINEGRP      79300057
         AIF   (&I LT &NLG).IL1    BR IF NOT LAST LINE IN WHOLE SYSTEM  79400057
&TNAME   SETC  'TLAST'             BUILD SPECIAL NAME FOR LAST LINE     79500057
         AGO   .IL2                SKIP NORMAL NAME BUILDING            79600057
.IL1     ANOP                                                           79700057
&K       SETA  &K+1                BUMP TTABLE NAME COUNTER             79800057
&TNAME   SETC  'T&K'               BUILD TTABLE ENTRY NAME              79900057
.IL2     ANOP                                                           80000057
&ADRPT   SETA  &ADRPT+1            BUMP ADCHAR ARRAY POINTER            80100057
&Y       SETC  ''                                                       80200057
&X       SETC  '&ADCHAR(&ADRPT)'   ASSUME NOT 1050 OR 226R/5 OR 327R    80300057
         AIF   ('&X' EQ '').ILPAST  SKIP PROCESSING IF NULL             80400057
         AIF   ('&T(&I)' EQ '327R' OR '&T(&I)' EQ '327S').IL327R        80500057
         AIF   ('&T(&I)' NE '226R' AND '&T(&I)' NE '2265').IL1050       80600057
&X       SETC  '&X'(1,4)'40'                                            80700057
         AGO   .ILPAST3                                                 80800057
.IL327R  ANOP                                                           80900057
&X       SETC  '&X'(1,2)'&X'(1,2)'&X'(3,2)'&X'(3,2)                     81000057
.*                                 REPLICATING ADDRESSING CHARS         81100057
         AIF   ('&TTAB((&I-1)*4+1)' EQ 'ASCI').ASCITAB                  81200057
&Y       SETC  '2D'                     SET ENQ FOR EBCD                81300057
&EOT     SETC  ',EOT=37'                                                81400057
         AGO   .ILPAST3                                                 81500057
.ASCITAB ANOP                                                           81600057
&Y       SETC  '05'                     SET ENQ FOR ASCI                81700057
&EOT     SETC  ',EOT=04'                                                81800057
         AGO   .ILPAST3                                                 81900057
.IL1050  ANOP                                                           82000057
         AIF   ('&T(&I)' NE '1050' AND '&T(&I)' NE '5041').ILPAST       82100057
&X       SETC  '&X'(1,2)'15'       ADD COMPONENT SELECTOR               82200057
         AGO   .ILPAST3                                                 82300057
.ILPAST  ANOP                                                           82400057
         AIF   ('&T(&I)' NE '226L' AND '&T(&I)' NE '327L').ILPAST2      82500057
.*                                 TEST FOR 226L AND 327L               82600057
         AIF   ('&T(&I)' EQ '327L').IL327L                              82700057
&X       SETC  '02'                SET 226L INVLIST VALUE               82800057
         AGO   .ILPAST3                                                 82900057
.IL327L  ANOP                                                           83000057
&X       SETC  '06'                SET 327L INVLIST VALUE               83100057
         AGO   .ILPAST3                                                 83200057
.ILPAST2 ANOP                                                           83300057
         AIF   ('&X' NE '').ILPAST3                                     83400057
&X       SETC  'DF'                SET DEFAULT VALUE                    83500057
.ILPAST3 ANOP                                                           83600057
.*       COMPUTE VALUES FOR SELECTION OF CHARACTERS IN THE              83700057
.*       ALPHAMERIC CHARACTER SET ARRAY.  THESE TWO SELECTED CHARACTERS 83800057
.*       WILL BE CONCATENATED TO FORM THE INVLIST MACRO NAME.           83900057
&L       SETA  (&IN-1)/36+1        SET 1ST CHARACTER SELECTOR           84000057
&M       SETA  &IN-(&L-1)*36       SET 2ND CHAR SELECTOR                84100057
         AIF   ('&T(&I)' NE '3335').IVLNTWX  BR IF NOT TWX              84200057
&IN      SETA  &IN+1               BUMP INVLIST MACRO COUNTER           84300057
 PUNCH '&CS(&L)&CS(&M)       INVLIST ORDER=(&TNAME+89),CPUID=CPID'      84400057
&CPIDSW  SETB  1                   INDICATE CPU.ID. CONSTANT NEEDED     84500057
         AGO   .IVLPND             GO TO LOOP MODIFICATION              84600057
.IVLNTWX ANOP                                                           84700057
&MM      SETA  (&N-((&N-1)/14)*14) CONVERT TO MODULO 14                 84800057
         AIF   (&N GE &TRMNO(&SCRPT)).ILEOL BR IF LAST INVLIST ENTRY    84900057
         AIF   (&MM EQ 14).ILEOG   BR IF END OF GROUP OF 14             85000057
         AIF   (&N GT 1 AND &MM NE 1).ILPMID  BR IF NOT FIRST OR LAST   85100057
 PUNCH '&CS(&L)&CS(&M)       INVLIST ORDER=(&TNAME+&X&Y,               X85200057
                              .........'                                85300057
         AGO   .IVLPND             GO TO LOOP MODIFICATION              85400057
.ILPMID  ANOP                      PUNCH NOT-FIRST/NOT-LAST ENTRY       85500057
 PUNCH '               &TNAME+&X&Y,                                    X85600057
                  .........'                                            85700057
         AGO   .IVLPND             GO TO LOOP MODIFICATION              85800057
.ILEOG   ANOP                                                           85900057
&Y       SETC  '&Y'.','            ADD COMMA                            86000057
         AGO   .ILPLAST            GO PUNCH LAST ENTRY                  86100057
.ILEOL   ANOP                      END OF THIS INVLIST MACRO            86200057
&IN      SETA  &IN+1               BUMP INVLIST MACRO COUNTER           86300057
         AIF   (&MM EQ 1).ILFAL    BR IF 1ST & LAST ENTRY               86400057
.ILPLAST ANOP                                                           86500057
 PUNCH '               &TNAME+&X&Y),AUTO=NO&EOT'               @YA14062 86600057
         AGO   .IVLPND             GO TO LOOP MODIFICATION              86700057
.ILFAL   ANOP                      PUNCH FIRST-AND-LAST ENTRY           86800057
 PUNCH '&CS(&L)&CS(&M)       INVLIST ORDER=(&TNAME+&X&Y),AUTO=NO&EOT'   86900057
.IVLPND  ANOP                                                           87000057
&N       SETA  &N+1                BUMP INNERMOST LOOP COUNTER          87100057
         AGO   .IVL3               GO TO INNERMOST LOOP TEST            87200057
.IVL2T   ANOP                                                           87300057
&SCRPT   SETA  &SCRPT+1            BUMP TRMNO ARRAY POINTER             87400057
&J       SETA  &J+1                BUMP INNER LOOP CONTROL VARIABLE     87500057
         AGO   .IVL2               GO INCREMENT INNERMOST LOOP CTR      87600057
.IVL1T   ANOP                                                           87700057
&I       SETA  &I+1                BUMP OUTER LOOP CONTROL VARIABLE     87800057
         AIF   (&I LE &NLG).IVL1   BR IF ALL LINEGRP'S NOT HANDLED      87900057
.*                                                                      88000057
         AIF   (NOT &CPIDSW).TSOMH  BR IF NOT TWX TERMINAL              88100057
 PUNCH 'CPID     DC    X''0289C9'''     NON-PARITY ID           SA70240 88300057
.TSOMH   ANOP                                                           88700057
.*                                                                      88800057
.*********************************************************************  88900057
.*       TSOMH                                                          89000057
.*********************************************************************  89100057
.*                                                                      89200057
TSOMH    TSOMH                                                          89300057
.*                                                                      89400057
 PUNCH '         DCBD  DSORG=TX'                                        89500057
.ALLTHRU ANOP                                                           89600057
 PUNCH '         END'                                                   89700057
         MEND                                                           89800057
